home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib15.dsk / FUNCTION GRAPHER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  1KB  |  49 lines
  1. 10  REM  **********************
  2. 11  REM  *  FUNCTION GRAPHER  *
  3. 12  REM  * BY MERRIL ROBERTS  *
  4. 13  REM  * COPYRIGHT (C) 1983 *
  5. 14  REM  * BY MICROSPARC, INC *
  6. 15  REM  * LINCOLN, MA. 01773 *
  7. 16  REM  **********************
  8. 110  REM  LINES 430 AND 440 CONTAIN THE EQUATIONS.
  9. 120  REM  JUST TYPE IN NEW EQUATIONS IN THESE TWO LOCATIONS
  10. 130  TEXT : HOME : PRINT "** COPYRIGHT 1983 BY MICROSPARC, INC. **": VTAB 22
  11. 140  INPUT "X AXIS (NEG , POS)";A,B
  12. 150  INPUT "Y AXIS (NEG , POS)";C,D
  13. 160 W =  ABS( INT(A)) + ABS( INT(B))
  14. 170 V =  ABS( INT(C)) + ABS( INT(D))
  15. 175  IF W <1  OR V <1  THEN  PRINT "PARAMETERS NOT LARGE ENOUGH -REDO PLEASE": GOTO 140
  16. 180 G = 279/W
  17. 190 H = 159/V
  18. 200 I =  ABS( INT(A)) *G
  19. 210 J =  ABS( INT(C)) *H
  20. 220  HOME : VTAB 21: LIST 430 -440
  21. 230  VTAB 21: PRINT "    ": VTAB 22: PRINT "    "
  22. 240  HGR 
  23. 250  HCOLOR= 3
  24. 260  HPLOT 0,J TO 279,J
  25. 270  HPLOT I,0 TO I,159
  26. 280  FOR X = 0 TO 159  STEP H
  27. 290  IF I < = .5  THEN 310
  28. 300  HPLOT I -1,X
  29. 310  IF I > = 158.5  THEN 330
  30. 320  HPLOT I +1,X
  31. 330  NEXT X
  32. 340  FOR Y = 0 TO 279  STEP G
  33. 350  IF J < = .5  THEN 370
  34. 360  HPLOT Y,J -1
  35. 370  IF J > = 278.5  THEN 390
  36. 380  HPLOT Y,J +1
  37. 390  NEXT Y
  38. 400  HCOLOR= 5
  39. 410  FOR Q = 0 TO 279
  40. 420 X = (Q/G) - ABS( INT(A))
  41. 430 Y = X ^2
  42. 440 Z = X ^3 -3 *X
  43. 450 S = H * ABS( INT(C)) -(Y *H)
  44. 460  IF S >0  AND S <159  THEN  HCOLOR= 5: HPLOT Q,S
  45. 470 P = H * ABS( INT(C)) -(Z *H)
  46. 480  IF P >0  AND P <159  THEN  HCOLOR= 6: HPLOT Q,P
  47. 490  NEXT Q
  48. 500  GOTO 140
  49. 510  END